利用宏命令批量去除word文档页眉与页脚

1、首先我们把要处理的文档放到一个文件夹里面，方便我们接下来进行处理。

2、如果是Wps文档的后缀名为.docx，这时我们需要修改成.doc，批量方法在上一条经验中有介绍，运行bat文件即可。

3、批量修改后的文档如图所示。

4、如果是WPS文档，我们需要选择打开的方式为word打开。如果已经是word文档，这一步可以跳过。

5、选择全部为word打开方式。

6、选中视图选项卡下面的宏命令。

7、到这里我们选中编辑按钮。

8、接着我们输入这段代码，然后关闭窗口。

9、点击运行，出现对话框，我们选中需要去除页眉的所有文档。

10、去除后的文档显示，此时发现文档的页眉和页脚已经成功去除。

11、代码如下：

Option Explicit

Sub Example()    '此代码功能为列出指定文件夹中所有选取的WORD文件全路径名
    Dim myDialog As FileDialog, oDoc As Document, oSec As Section
    Dim oFile As Variant, myRange As Range
    On Error Resume Next
    '定义一个文件夹选取对话框
    Set myDialog = Application.FileDialog(msoFileDialogFilePicker)
    With myDialog
        .Filters.Clear    '清除所有文件筛选器中的项目
        .Filters.Add "所有 WORD 文件", "*.doc", 1    '增加筛选器的项目为所有WORD文件
        .AllowMultiSelect = True    '允许多项选择
        If .Show = -1 Then    '确定
            For Each oFile In .SelectedItems    '在所有选取项目中循环
                Set oDoc = Word.Documents.Open(FileName:=oFile, Visible:=False)
                For Each oSec In oDoc.Sections    '文档的节中循环
                    Set myRange = oSec.Headers(wdHeaderFooterPrimary).Range
                    myRange.Delete    '删除页眉中的内容
                    myRange.ParagraphFormat.Borders(wdBorderBottom).LineStyle = wdLineStyleNone    '段落下边框线
                    Set myRange = oSec.Footers(wdHeaderFooterPrimary).Range
                    myRange.Delete    '删除页脚中的内容
                Next
                oDoc.Close True
            Next
        End If
    End With
End Sub